ge_s: Wasm Textinstruktion

Probieren Sie es aus

(module
  (import "env" "log_bool" (func $log_bool (param i32)))
  (func $main
    ;; load 10 and 3 onto the stack
    i32.const 10
    i32.const 3

    i32.ge_s ;; check if 10 is greater than or equal to 3
    call $log_bool ;; log the result
  )
  (start $main)
)

const url = "{%wasm-url%}";

function log_bool(value) {
  console.log(Boolean(value));
  // Expected output: true
}

await WebAssembly.instantiateStreaming(fetch(url), {
  env: { log_bool },
});

Syntax

value_type.ge_s

value_type

Der Typ des Wertes, auf dem die Instruktion ausgeführt wird. Die folgenden Typen unterstützen ge_s:

• i32
• i64
• v128-Interpretationen:
  • i8x16
  • i16x8
  • i32x4
  • i64x2

ge_s

Die ge_s-Instruktion. Muss immer nach dem value_type und einem Punkt (.) eingefügt werden.

Typ

[input1, input2] -> [output]

input1

Der erste Eingabewert.

input2

Der zweite Eingabewert.

output

Der Ausgabewert, der ein Ganzzahltyp sein wird.

Bei einem nicht-SIMD ge_s sind die Eingaben einfache numerische Werte wie 3 oder 12. Wenn der erste Eingabewert größer oder gleich dem zweiten Eingabewert ist, wird 1 als Ausgabe auf den Stapel geschoben, andernfalls 0.

Bei einem SIMD ge_s sind die Eingaben v128-Wertinterpretationen, zum Beispiel i32x4 2 30 86 120. Jedes Lane der Ausgabe, das auf den Stapel geschoben wird, ist eine 1 oder 0, die anzeigt, ob das entsprechende Lane des ersten Eingabewertes größer oder gleich dem entsprechenden Lane des zweiten Eingabewertes ist.

Binärcodierung

Beispiele

SIMD ge_s Beispiel

In diesem Beispiel demonstrieren wir die Verwendung von ge_s, um zu testen, ob ein SIMD-Lane-Wert größer oder gleich dem gleichen Lane-Wert in einem anderen SIMD-Wert ist.

JavaScript

In unserem Skript holen wir uns eine Referenz zu einem <p> Element, zu dem wir unser Ergebnis ausgeben werden, und definieren ein Objekt zum Importieren in Wasm mit einer einzigen Funktion, die einen Wert an das Ausgabe-<p> schreibt. Dann kompilieren und instanziieren wir unser Wasm-Modul mit der Methode WebAssembly.instantiateStreaming() und importieren dabei das Objekt.

<p></p>

const outputElem = document.querySelector("p");

const obj = {
  output(val) {
    outputElem.textContent += val;
  },
};

WebAssembly.instantiateStreaming(fetch("{%wasm-url%}"), {
  obj,
});

Wasm

In unserem Wasm-Modul importieren wir zuerst die JavaScript-Funktion output(), wobei wir sicherstellen, dass sie ein i32-Parameter besitzt. Wir deklarieren dann zwei SIMD-i32x4-Werte und überprüfen, ob die Lane-Werte des ersten größer oder gleich denen des zweiten sind, indem wir i32x4.ge_s verwenden. Schließlich extrahieren wir den Wert, der in Lane 3 des Ausgabewertes gespeichert ist, mit der extract_lane-Instruktion und geben ihn an das DOM aus, indem wir die importierte output()-Funktion aufrufen.

(module
  ;; Import output function
  (import "obj" "output" (func $output (param i32)))

  (func $main
    ;; load two SIMD values onto the stack
    v128.const i32x4 20 12 15 102
    v128.const i32x4 20 12 15 100

    ;; check whether the first value is greater than or equal to the second
    i32x4.ge_s
    i32x4.extract_lane 3 ;; Extract a value from the result

    call $output
  )

  (start $main)
)

Ergebnis

Die Ausgabe ist wie folgt:

Das Ergebnis ist 1, da der in Lane 3 des ersten Eingabewertes gespeicherte Wert größer oder gleich dem in Lane 3 des zweiten Eingabewertes gespeicherten Wert ist.

Siehe auch

• ge
• ge_u