global: Wasm-Definition

Probieren Sie es aus

(module
  (import "console" "log" (func $log (param i32)))

  ;; Import a global variable from js
  (import "env" "from_js" (global $from_js i32))

  ;; Create a global variable
  (global $from_wasm (mut i32) (i32.const 10))

  (func $main
    ;; Set $from_wasm to a different value
    i32.const 20
    global.set $from_wasm

    ;; Load both global variables onto the stack
    global.get $from_js
    global.get $from_wasm

    i32.add ;; Add up both globals
    call $log ;; Log the result
  )
  (start $main)
)

const url = "{%wasm-url%}";
const from_js = new WebAssembly.Global({ value: "i32", mutable: false }, 5);
await WebAssembly.instantiateStreaming(fetch(url), {
  console,
  env: { from_js },
});

Syntax

global identifier type initial_value

global

Der global Definitionstyp. Muss immer zuerst enthalten sein.

identifier Optional

Ein Bezeichnungsname für die globale Variable. Dieser muss mit einem $-Symbol beginnen, beispielsweise $my_global.

type

Der Typ der zu erstellenden globalen Variable. Dieser besteht aus einem data_type, optional vorausgegangen von dem Schlüsselwort mut:

mut Optional

Das mut Flag. Wenn es enthalten ist, ist die globale Variable veränderlich — sie kann nach der Initialisierung durch die global.set-Instruktion auf einen anderen Wert gesetzt werden.

data_type

Der Datentyp der globalen Variable. Dies kann einer der folgenden sein:

• i32
• i64
• f32
• f64
• v128
• funcref
• externref
• Andere Referenztypen wie Strukturen (zum Beispiel structref), Ausnahmen (zum Beispiel exnref), i31 (i31ref), usw.

initial_value

Der Initialisierer für die neue globale Variable. Sein Wert kann sein:

• Ein literaler Wert, beispielsweise i32.const 0.
• Ein global.get einer anderen globalen Variable.
• Jeder andere Konstantausdruck.

Der Typ von initial_value muss derselbe sein wie der deklarierte type.

Beschreibung

Die WebAssembly-global Definition ermöglicht die Definition von globalen Variablen innerhalb eines Wasm-Moduls. Globale Variablen können:

• Über global.get abgerufen und von überall im Modul verwendet werden.

• Über global.set verändert werden, sofern das mut Flag beim Deklarieren der globalen Variable enthalten war. Der Versuch, eine nicht veränderliche Variable zu mutieren, führt zu einem Validierungsfehler.

• Exportiert werden, um sie nach JavaScript zu übergeben. Zum Beispiel:

  wat

  (global $my_global (mut i32) (i32.const 0))
  (export "my_global" (global $my_global))
  

Erstellen von globalen Variablen aus JavaScript

Es ist auch möglich, eine Wasm-Globale vom JavaScript-Host aus mit dem WebAssembly.Global()-Konstruktor zu erstellen und anschließend in das Modul zu importieren.

Zum Beispiel:

const myGlobal = new WebAssembly.Global({ value: "i32", mutable: true }, 0);

const { instance } = await WebAssembly.instantiateStreaming(
  fetch("example.com/module"),
  {
    env: { myGlobal },
  },
);

Teilen von globalen Variablen zwischen Modulen

Es ist möglich, im Wasm-Modul oder im JavaScript-Host deklarierte globale Variablen zwischen mehreren Modulen zu teilen.

Zum Beispiel wird der unten erstellte globale Zustand zwischen zwei verschiedenen Modulen geteilt:

const shared = new WebAssembly.Global({ value: "i32", mutable: true }, 0);

const modA = await instantiate(bytesA, { env: { shared } });
const modB = await instantiate(bytesB, { env: { shared } });

Spezifikationen

Browser-Kompatibilität

Siehe auch

• global.get
• global.set
• WebAssembly.Global JavaScript-Schnittstelle